Programme gw basic donnant l'angle

horaire et la déclinaison

d'un point choisi de l'écliptique

pour un temps sidéral donné

par Jean Pakhomoff

gnomoniste à Marseille

 

5 REM CADTS1 programme donnant l'angle horaire d'un point de l'écliptique pour un temps sidéral donné. Utile pour la construction des heures sidérales sur un cadran solaire. jean Pakhomoff 20/2/2004

6 OPEN "CADTS1.wps" FOR OUTPUT AS #1

7 DEFDBL A-Z: PI=4#*ATN(1#)

10 INPUT "Valeur d'Epsilon en ° ?", EE:E=EE*PI/180#

20 INPUT "Longitude écliptique choisie en ° ?",LL:L=LL*PI/180#

30 INPUT "Temps sidéral choisi en heures ?",TT:T=TT*15#*PI/180#

40 D=SIN (E)*SIN (L):REM d=valeur de sin a a étant la déclinaison

45 D=ATN(D/SQR(1#-D^2#)):REM valeur de l'arc a donné par la formule de l'arc tangente en utilisant la valeur du sinus. On prend ici le résultat sans correction et avec son signe car abs(d)<pi/2.

50 A=COS (L)/ COS (D):REM a étant l'ascension droite

55 IF LL=90# THEN A=PI/2#:GOTO 70

56 IF LL=270# THEN A=PI/2#:GOTO 70:REM les lignes 55 et 56 évitent des quantités infinitésimales avec signe inversé pour désigner la valeur 0

57 REM L'inversion de signe entraînant des erreurs sur le résultat dans les conditions des lignes 70, 80, 90.

60 A=ATN(SQR(1#-A^2)/A):REM valeur de l'arc a donné par la formule de l'arc tangente en utilisant la valeur du cosinus.

70 IF L>=3#*PI/2# THEN 140

80 IF L>=PI THEN 130

90 IF L>PI/2# THEN 120

100 REM cas où l<=pi/2. On garde alors la valeur de a de la ligne 60.

110 GOTO 160

120 A=PI+A:GOTO 160:REM l>pi/2 et < pi

130 A=PI-A:GOTO 160:REM l>=pi et <3pi/2

140 A=2#*PI-A:GOTO 160:REM l>=3pi/2 et <=2pi

150 REM Tous les 90° les ascensions droites et longitudes s'égalisent. C'est pour cette raison que l'on peut se servir des valeurs de l pour appliquer les corrections ci-dessus à a:

151 REM l et a sont toujours dans le même cadran de sphère céleste. l<pi/2 ==> a<pi/2; l<pi==>a<pi etc....

160 H=T-A:IF H>0 THEN 180

170 H=H+2#*PI

180 IF H<=PI THEN A$="Post-Méridien":GOTO 200

190 H=2#*PI-H:A$="Anté-Méridien":REM C'est le cas du côté EST de la sphère céleste et dans mes programmes de cadrans je prends les angles horaires de 0 à 180° en Ouest comme en Est.

200 PRINT"Longit écl= ";LL;"° TSid= ";TT;"h Déclin= ";FIX(D*1800000#/PI)/10000#;"° Alpha= ";FIX(A*1800000#/PI)/10000#;"° AnglHor= ";FIX(H*1800000#/PI)/10000#;"° ";A$

205 PRINT #1,"Longit écl= ";LL;"° TSid= ";TT;"h Déclin= ";FIX(D*1800000#/PI)/10000#;"° Alpha= ";FIX(A*1800000#/PI)/10000#;"° AnglHor= ";FIX(H*1800000#/PI)/10000#;"° ";A$

210 INPUT" Autre angle horaire appuyez sur h; arrêt sur a",J$

220 IF J$="h" THEN 20

230 CLOSE:END

retour à la page précédent

retour au menu

Google
Web pakhomoff.net
de-la-parra.com